Có cách nào để chuyển toán tử số học và logic như một tham số phương thức trong VBA không?

Question

Đã qua một vài tình huống mà một người muốn vượt qua operators dưới dạng parameter trong một hàm hoặc phương pháp. According to this post Java doesn't have that ability, hence need to create an Enum as the primary workaround.

Ví dụ:

Function doCalcs(ByRef AND as LogicalOperator, ByRef greater ArithmeticOperator) 

Mặc dù VBA có thư viện ít hơn nhiều so với .Net, Java, tạo Enum cũng được hỗ trợ. Có lẽ tôi không biết, vì vậy nếu có khả năng VBA có operator types hoặc bất kỳ giải pháp nào khác, chúng tôi có thể vượt qua an operator, bắn điều đó. (Ngoài if else/case để kiểm tra chuỗi chứa tham số điều hành .. =)) Tôi yêu cầu là different from what's mentioned here.

• Câu hỏi được hỏi về giảm mã, tối ưu hóa.

Ví dụ: Nếu bạn nhìn vào CountIFS, nó có khả năng thực hiện trong operators. Thậm chí nếu ai đó có thể giải thích công việc back-end có thể trong chức năng này,

1. Làm thế nào để nó chuyển đổi các chuỗi thành một hợp operator?
2. Đó có phải là cấu trúc Enum hoặc bất kỳ thứ gì hiệu quả hơn số đó hoặc nhỏ hơn không?

Câu trả lời cho những câu hỏi này vẫn được chấp nhận.

Answer 1

Một cách tiếp cận sử dụng các lớp:

Định nghĩa một lớp giao diện

Op

Public Function eval(operand1, operand2) 
End Function 

Đối với mỗi nhà khai thác mong muốn, xác định một thực hiện.Ví dụ

OpMinus

Implements Op 

Private Function Op_eval(operand1 As Variant, operand2 As Variant) As Variant 
    Op_eval = operand1 - operand2 
End Function 

OpPlus

Implements Op 

Private Function Op_eval(operand1 As Variant, operand2 As Variant) As Variant 
    Op_eval = operand1 + operand2 
End Function 

Bây giờ một số thói quen kiểm tra trong một mô-đun:

Sub test() 
    Dim Minus As New OpMinus 
    Dim Plus As New OpPlus 
    Dim o, v1, v2 

    For Each o In Array(Minus, Plus) 
     For Each v1 In Array(1, 2, 3) 
      For Each v2 In Array(1, 2, 3) 
       operate o, v1, v2 
      Next 
      Debug.Print "" 
     Next 
     Debug.Print "" 
    Next 
End Sub 

Sub operate(ByVal operator As Op, operand1, operand2) 
    Debug.Print operator.eval(operand1, operand2), 
End Sub 

outpu t:

0   -1   -2    
1    0   -1    
2    1    0    

2    3    4    
3    4    5    
4    5    6    

Lưu ý bạn có thể muốn sử dụng ví dụ: Double thay vì Variant trong giao diện nếu bạn biết loại bạn sẽ hoạt động.

Answer 2

Không có loại LogicalOperator, ArithmeticOperator type hoặc bất kỳ thứ gì tương tự. Về gần nhất bạn có thể đến là sử dụng chức năng Eval trong MS Access VBA hoặc chức năng Evaluate (tương tự nhưng khác) trong Excel VBA.

Thực tế, bạn có thể đã sử dụng chức năng Evaluate trong Excel mà không hề nhận ra nó. Từ Excel tập tin trợ giúp:

Note Sử dụng dấu ngoặc vuông (ví dụ, "[A1: C5]") là giống với cách gọi phương thức Đánh giá với một đối số chuỗi. Ví dụ, các cặp biểu thức sau đây là tương đương.

[a1].Value = 25 
Evaluate("A1").Value = 25 

Answer 3

Làm thế nào tôi sẽ giải quyết vấn đề

1) Tham khảo Microsof Script Controler 1.0 thư viện

Option Explicit 

Sub Base_Sub() 

Dim iNumber1  As Integer 
Dim iNumber2  As Integer 
Dim iSum   As Integer 
Dim iMultiply  As Integer 
Dim dDivision  As Double 
Dim iDifference  As Integer 
Dim lPower   As Long 

iNumber1 = 2 
iNumber2 = 6 

iSum = CalculateThis("+", iNumber1, iNumber2) 
iMultiply = CalculateThis("*", iNumber1, iNumber2) 
iDifference = CalculateThis("-", iNumber1, iNumber2) 
dDivision = CalculateThis("/", iNumber1, iNumber2) 
lPower = CalculateThis("^", iNumber1, iNumber2) 

End Sub 



Public Function CalculateThis(operator As String, iNumber1 As Integer, iNumber2 As Integer) 

Dim script As ScriptControl 

Set script = New ScriptControl 
script.Language = "VBScript" 

CalculateThis = script.Eval(iNumber1 & operator & iNumber2) 

End Function