Chuyển đổi chuỗi "abc" đến $ băm -> {a} -> {b} -> {c} trong Perl

Question

Tôi đã động lồng nhau băm-refs như thế này:

my $hash = { 'a' => { 'b' => { 'c' => 'value' } } }; 

Tôi muốn thiết giá trị của c thành 'something' bằng cách cho phép người dùng nhập "abc something".

Bây giờ nhận giá trị có thể được thực hiện như thế này:

my $keys = 'a.b.c'; 
my $v='something'; 
my $h = $hash; 
foreach my $k(split /\./, $keys) { 
    $h = $h->{$k}; 
} 
print $h; # "value" 

Nhưng làm thế nào sẽ Tôi thiết giá trị của chính c-$v để

print Dumper $hash; 

sẽ phản ánh sự thay đổi ? $h không phải là ref ở cuối vòng lặp foreach, do đó thay đổi sẽ không phản ánh thay đổi trong $hash. Bất kỳ gợi ý làm thế nào để giải quyết các nút thắt trong đầu của tôi?

Answer 1

Something như thế này:

my $h = $hash; 
my @split_key = split /\./, $keys; 
my $last_key = pop @split_key; 
foreach my $k (@split_key) { 
    $h = $h->{$k}; 
} 
$h->{$last_key} = $v; 

Answer 2

use strictures; 
use Data::Diver qw(DiveVal); 

my ($hash, $path, $value) = (
    { 'a' => { 'b' => { 'c' => 'value' } } }, 
    'a.b.c', 
    'something', 
); 

DiveVal($hash, split /[.]/, $path) = $value; 
# { a => { b => { c => 'something' } } } 

Answer 3

Popping ra chìa khóa cuối cùng là cho wusses! ;)

sub dive :lvalue { 
    my $r = \shift; 
    $r = \(($$r)->{$_}) for @_; 
    return $$r; 
} 

my $data; 
my $key = 'a.b.c'; 
my $val = 'value'; 

dive($data, split /\./, $key) = $val; 

Phiên bản mạnh hơn (và do đó khó sử dụng hơn) của chức năng này được cung cấp bởi Data::Diver.

use Data::Diver qw(DiveVal); 

my $data; 
my $key = 'a.b.c'; 
my $val = 'value'; 

DiveVal($data //= {}, map \$_, split /\./, $key) = $val; 

(sử dụng daxim là hơi off.)