Làm thế nào để đặt hình ảnh vòng viền trong Outlook theo mặc định

Question

Đây là một cái gì đó đã gây phiền nhiễu cho tôi trong nhiều tháng, nếu không phải là năm. Khi tôi dán hình ảnh vào email Outlook, nó không có đường viền. Tôi có thể thêm chúng bằng cách nhấp chuột phải vào ảnh và chọn Định dạng Ảnh và có thể cũng có công cụ để thực hiện việc này. Câu hỏi của tôi là: có cách nào để đảm bảo rằng tất cả hình ảnh được dán đều có đường viền không? Nếu có một bảng định kiểu CSS cho Outlook, tôi có thể làm điều này ở đây; hoặc có thể có một thiết lập ở đâu đó?

Cảm ơn trước!

Answer 1

Bạn có thể xem xét để cung cấp macro VBA (cộng với phím tắt cho nó). Không chắc chắn cách này làm việc cho biên giới hình ảnh, nhưng đối với chọn trong email văn bản ở đây là một ví dụ đơn giản:

Sub ChangeSelectedExample() 
    Set insp = Application.ActiveInspector 
    If insp.CurrentItem.Class = olMail Then 
     Set mail = insp.CurrentItem 
     If insp.EditorType = olEditorHTML Then 
      txt = ActiveInspector.HTMLEditor.Selection.CreateRange.Text 
        ActiveInspector.HTMLEditor.Selection.CreateRange.Text = txt & "<hello world 1>" 
     ElseIf insp.EditorType = olEditorWord Then 
      txt = insp.CurrentItem.GetInspector.WordEditor.Application.Selection.Text 
        insp.CurrentItem.GetInspector.WordEditor.Application.Selection = txt & "<hello world 2>" 
     Else 
      MsgBox ("not supported mail format") 
     End If 
    Else 
     MsgBox ("not supported view type") 
    End If 
End Sub 

Answer 2

Tôi đã có một Word 2010 macro cho biết thêm một biên giới để hình ảnh và tập trung họ:

Sub AddBlueBorderAndCenterImages() 
    Dim oIshp As InlineShape 
    Dim oshp As Shape 

    For Each oIshp In ActiveDocument.InlineShapes 'in line with text 
     With oIshp.Borders 
      .OutsideLineStyle = wdLineStyleSingle 
      .OutsideLineWidth = wdLineWidth025pt 
      .OutsideColor = RGB(0, 112, 192) 
     End With 
     oIshp.Select 
     Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter 
    Next oIshp 

    For Each oshp In ActiveDocument.Shapes 'floating with text wraped around 
     With oshp.Line 
      .Style = msoLineSingle 
      .Weight = 0.25 
      .ForeColor.RGB = RGB(0, 112, 192) 
     End With 
    Next oshp 

    Selection.HomeKey Unit:=wdStory 'go back to top of doc 
End Sub 

Tôi đã thử điều chỉnh nó với Outlook, điều chính là cố gắng truy nhập ActiveDocument của Word từ một mục Outlook.

Vì vậy, đây là phiên bản Outlook (không có bất kỳ định tâm):

Sub AddBlueBorders() 
    Set insp = Application.ActiveInspector 
    If insp.CurrentItem.Class = olMail Then 
     Set mail = insp.CurrentItem 
     If insp.EditorType = olEditorWord Then 
      Set wordActiveDocument = mail.GetInspector.WordEditor 

      For Each oIshp In wordActiveDocument.InlineShapes 'in line with text 
       With oIshp.Borders 
        .OutsideLineStyle = wdLineStyleSingle 
        '.OutsideLineWidth = wdLineWidth025pt ' error: one of the values passed to this method or property is out of range 
        .OutsideColor = RGB(0, 112, 192) 
       End With 
      Next oIshp 

      For Each oshp In wordActiveDocument.Shapes 'floating with text wraped around 
       With oshp.Line 
        .Style = msoLineSingle 
        .Weight = 0.25 
        .ForeColor.RGB = RGB(0, 112, 192) 
       End With 
      Next oshp 

     'ElseIf insp.EditorType = olEditorHTML Then 
     'Something else here, maybe using css? 

     End If 
    End If 
End Sub 

Đối với một số lý do, điều này không thêm một biên giới để một logo công ty tôi có trong chữ ký của tôi, có lẽ vì nó ở một chân hoặc phần tài liệu khác.

Đây không phải là mặc định và không tự động thêm đường viền cho hình ảnh khi chúng được dán/thêm vào email. Bạn vẫn phải liên kết macro này bằng nút hoặc phím tắt. Nhưng hy vọng nó sẽ giúp, thậm chí 4 tháng sau đó.

Mơ hồ lấy cảm hứng từ http://en.allexperts.com/q/Microsoft-Word-1058/Word-resize-pictures.htm