Thực hiện các xét nghiệm Geb cụ thể theo môi trường

Question

Tôi có một tập hợp các kiểm tra Spec mà tôi đang thực hiện trong một dự án Grails.

Tôi cần phải thực hiện một số thông số kỹ thuật nhất định khi tôi ở địa phương và một bộ Spec khác khi tôi chạy môi trường trước sản phẩm. Cấu hình hiện tại của tôi đang thực hiện tất cả thông số kỹ thuật của tôi cùng một lúc cho cả hai môi trường, đó là điều tôi muốn tránh.

Tôi có nhiều môi trường, mà tôi đã cấu hình trong GebConfig tôi:

environments { 
    local { 
     baseUrl = "http://localhost:8090/myApp/login/auth" 
    } 

    pre-prod { 
     baseUrl = "https://preprod/myApp/login/auth" 
    } 

} 

Answer 1

Bạn có thể sử dụng một tập tin Spock config.

Tạo chú thích cho hai loại thử nghiệm - @Local và @PreProd, ví dụ như trong Groovy:

import java.lang.annotation 

@Retention(RetentionPolicy.RUNTIME) 
@Target([ElementType.TYPE, ElementType.METHOD]) 
@Inherited 
public @interface Local {} 

Bước tiếp theo là để chú thích thông số kỹ thuật của bạn cho phù hợp, ví dụ:

@Local 
class SpecificationThatRunsLocally extends GebSpec { ... } 

Sau đó tạo a SpockConfig.groovy tệp bên cạnh tệp GebConfig.groovy của bạn với các nội dung sau:

def gebEnv = System.getProperty("geb.env") 
if (gebEnv) { 
    switch(gebEnv) { 
     case 'local': 
      runner { include Local } 
      break 
     case 'pre-prod': 
      runner { include PreProd } 
      break 
    } 
} 

EDIT: Có vẻ như Grails đang sử dụng nhân vật thử nghiệm riêng của nó có nghĩa là SpockConfig.groovy không được tính đến khi chạy thông số kỹ thuật từ Grails. Nếu bạn cần nó để làm việc dưới Grails thì bạn nên sử dụng @ IgnoreIf/@ Require chú thích mở rộng được xây dựng trong Spock.

Trước tiên, hãy tạo một lớp Đóng với logic khi có một thông số cụ thể được cho phép. Bạn có thể đặt logic trực tiếp như là một đối số đóng cửa cho các chú thích mở rộng nhưng nó có thể gây phiền nhiễu để sao chép mã bit đó khắp nơi nếu bạn muốn chú thích nhiều thông số kỹ thuật.

class Local extends Closure<Boolean> { 
    public Local() { super(null) } 
    Boolean doCall() { 
     System.properties['geb.env'] == 'local' 
    } 
} 

class PreProd extends Closure<Boolean> { 
    public PreProd() { super(null) } 
    Boolean doCall() { 
     System.properties['geb.env'] == 'pre-prod' 
    } 
} 

Và rồi chú thích thông số kỹ thuật của bạn:

@Requires(Local) 
class SpecificationThatRunsLocally extends GebSpec { ... } 

@Requires(PreProd) 
class SpecificationThatRunsInPreProd extends GebSpec { ... }