Làm thế nào để có được tên của ứng dụng frontmost với AppleScript và sử dụng nó để có được những filepath

Question

Những gì tôi cố gắng làm:

Khi tôi đang ở trong một trong soạn thảo văn bản của tôi (TextEdit, tục ngư, FoldingText) Tôi muốn AppleScript này để hiển thị đường dẫn tệp.

Tôi đã tìm ứng dụng cửa sổ ở phía trước giúp tôi có được tên ứng dụng đẹp và dễ dàng và sau đó tôi có thể yêu cầu đường dẫn POSIX trong bước tiếp theo.

Vấn đề:

Các kịch bản đã được 99% đó, nhưng tôi đang thiếu một cái gì đó. Khi tôi cố gắng sử dụng các biến của activeApp nó không hoạt động và tôi nhận được lỗi này:

Error Number:System Events got an error: Can’t get application {"TextEdit"}. 
-1728 

Đây là kịch bản:

tell application "System Events" 
    set activeApp to name of application processes whose frontmost is true 

    --This doesn't work either: 
    --do shell script "php -r 'echo urldecode(\"" & activeApp & "\");'" 

    tell application activeApp 
     set myPath to POSIX path of (get file of front document) 
    end tell 
    display dialog myPath 
end tell 

Nếu tôi trao đổi với activeApp"TextEdit" mọi thứ hoạt động. Trợ giúp sẽ được đánh giá cao.

Có thể có một cái gì đó ở đây giúp: Get process name from application name and vice versa, using Applescript

Answer 1

Hoặc lấy path sở hữu của một tài liệu hoặc sử dụng hệ thống sự kiện để có được value of attribute "AXDocument":

try 
    tell application (path to frontmost application as text) 
     (path of document 1) as text 
    end tell 
on error 
    try 
     tell application "System Events" to tell (process 1 where frontmost is true) 
      value of attribute "AXDocument" of window 1 
     end tell 
     do shell script "x=" & quoted form of result & " 
     x=${x/#file:\\/\\/} 
     x=${x/#localhost} # 10.8 and earlier 
     printf ${x//%/\\\\x}" 
    end try 
end try 

Phương pháp đầu tiên đã không làm việc với Preview, TextMate 2, Text Sublime, hoặc ICHM, và phương pháp thứ hai đã không làm việc với Acorn. Phương pháp thứ hai yêu cầu quyền truy cập cho các thiết bị trợ giúp được bật.

Answer 2

Bạn đang yêu cầu ...

set activeApp to name of application processes whose frontmost is true 

Thông báo "quá trình", đó là ý nghĩa số nhiều bạn có thể nhận được một số quy trình để đáp ứng nên AppleScript cung cấp cho bạn một danh sách các tên. Mặc dù chỉ có một ứng dụng được trả về, nó vẫn ở định dạng danh sách. Cũng thấy rằng lỗi của bạn chứa {"TextEdit"}. Các dấu ngoặc xung quanh tên có nghĩa là đó là một danh sách, do đó, lỗi sẽ hiển thị cho bạn sự cố.

Bạn không thể chuyển danh sách tên tới dòng mã tiếp theo. Như vậy bạn có một vài lựa chọn. 1) bạn chỉ có thể yêu cầu 1 quy trình thay vì tất cả các quy trình. Điều đó sẽ trả về một chuỗi thay vì một danh sách. Hãy thử mã này ...

set activeApp to name of first application process whose frontmost is true 

2) bạn có thể làm việc với danh sách bằng cách sử dụng "mục 1 của danh sách". Hãy thử mã này ...

set activeApps to name of application processes whose frontmost is true 
set activeApp to item 1 of activeApps 

Cuối cùng, bạn không nên thông báo cho các sự kiện của hệ thống để báo cho ứng dụng. Tách riêng 2 lệnh đó cho biết các khối mã. Đây là cách tôi sẽ viết mã của bạn.

tell application "System Events" 
    set activeApp to name of first application process whose frontmost is true 
end tell 

try 
    tell application activeApp 
     set myPath to POSIX path of (get file of front document) 
    end tell 

    tell me 
     activate 
     display dialog myPath 
    end tell 
on error theError number errorNumber 
    tell me 
     activate 
     display dialog "There was an error: " & (errorNumber as text) & return & return & theError buttons {"OK"} default button 1 with icon stop 
    end tell 
end try 

Tôi không thể đảm bảo mã "nhận tệp tài liệu trước" sẽ hoạt động. Điều đó phụ thuộc vào ứng dụng. Không phải tất cả các ứng dụng đều hiểu yêu cầu đó. Đó là lý do tại sao tôi sử dụng một khối thử. Trong mọi trường hợp, dù bạn có thể chắc chắn bạn đang giải quyết các ứng dụng thích hợp. Chúc may mắn.

Answer 3

Tôi đã sử dụng đoạn mã này trong một thời gian, dường như làm việc cho tất cả các ứng dụng Cocoa (không chắc chắn về X11):

set front_app to (path to frontmost application as Unicode text) 

tell application front_app 
    -- Your code here 
end tell 

Answer 4

Không ai trong số này dường như làm việc với một AppleScript biên soạn lưu lại dưới dạng một ứng dụng và đặt trên Dock. Bất cứ khi nào bạn chạy ứng dụng, CNTT là ứng dụng phía trước, không phải ứng dụng đang hiển thị cửa sổ trước của nó. Ứng dụng đó trở nên không hoạt động khi Applescript của tôi chạy. Làm thế nào để viết một ứng dụng Applescript không hoạt động khi nó chạy?

Tôi có thể đã tìm thấy giải pháp cho vấn đề được liệt kê ở trên. Chỉ cần yêu cầu người dùng kích hoạt lại ứng dụng mong muốn và cung cấp cho họ thời gian.

tell application "Finder" 
    activate 
    say "Click front window of your application" 
    delay 5 
    set myapp to get name of first application process whose frontmost is true 
-- etc. 
-- your code 
end tell