Làm cách nào để tìm tất cả các cột được điền bằng 100% null trong lược đồ cơ sở dữ liệu SQL Server của tôi?

Question

Có cách nào để tìm ra các cột trong lược đồ của tôi có đầy đủ các giá trị null không? Có một số trường trong một vài bảng mà tôi biết không được ứng dụng sử dụng và sẽ bị loại bỏ, nhưng tôi muốn xem liệu có cách tự động/tập lệnh để tìm ra điều này trên toàn bộ cơ sở dữ liệu không/có thể loại bỏ.

Chạy SQL Server 2005 trên x86 nếu nó quan trọng.

Cảm ơn trước!

Answer 1

create table #SuspectColumns (
    TABLE_SCHEMA sysname, 
    TABLE_NAME sysname, 
    COLUMN_NAME sysname 
) 

declare csrColumns cursor fast_forward for 
    select TABLE_SCHEMA, TABLE_NAME, COLUMN_NAME 
     from INFORMATION_SCHEMA.COLUMNS 
     where IS_NULLABLE = 'YES' 

declare @TABLE_SCHEMA sysname, 
     @TABLE_NAME sysname, 
     @COLUMN_NAME sysname, 
     @sql nvarchar(max) 

open csrColumns 

while (1=1) begin 
    fetch next 
     from csrColumns 
     into @TABLE_SCHEMA, @TABLE_NAME, @COLUMN_NAME 

    if @@FETCH_STATUS<>0 break 

    set @sql = N'if not exists(select 1 from ' + QUOTENAME(@TABLE_SCHEMA) + N'.' + QUOTENAME(@TABLE_NAME) + N' where ' + QUOTENAME(@COLUMN_NAME) + N'is not null) 
        insert into #SuspectColumns values (''' + @TABLE_SCHEMA + N''',''' + @TABLE_NAME + N''',''' + @COLUMN_NAME + N''')' 

    exec sp_executesql @sql 
end /* while */ 

close csrColumns 
deallocate csrColumns 

select * from #SuspectColumns 

drop table #SuspectColumns 

Answer 2

bạn có thể trả tối đa (cột) và kiểm tra null

Answer 3

Off đỉnh đầu của tôi, tôi tin rằng các lệnh SQL sau đây nên làm việc. Nó sẽ thực hiện một truy vấn cho mỗi kết hợp bảng/cột và truy vấn sẽ trả về tên bảng và tên cột nếu kết hợp bảng/cột đó không có hàng hoặc tất cả các hàng rỗng.

DECLARE @table_columns TABLE 
(
    table_name nvarchar(128), 
    column_name nvarchar(128) 
); 
DECLARE @table_name nvarchar(128); 
DECLARE @column_name nvarchar(128); 

INSERT INTO @table_columns(table_name, column_name) 
select TABLE_NAME, COLUMN_NAME from INFORMATION_SCHEMA.columns; 

while (select count(*) from @table_columns) > 0 
begin 
    select top 1 @table_name = table_name, @column_name = column_name from @table_columns 
    exec('SELECT ''' + @table_name + ''' as table_name, ''' + @column_name + ''' as column_name WHERE NOT EXISTS (SELECT TOP 1 * FROM ' + @table_name + ' WHERE ' + @column_name + ' IS NOT NULL)') 
    delete from @table_columns where table_name = @table_name and column_name = @column_name 
end