Gửi chuỗi dữ liệu từ chủ đề đến hình thức chính

Question

Trong Dephi, tôi tạo ra một chủ đề, như thế này, mà sẽ gửi thông điệp tới hình thức chính trong từng thời kỳ

Procedure TMyThread.SendLog(I: Integer); 
Var 
    Log: array[0..255] of Char; 
Begin 
    strcopy(@Log,PChar('Log: current stag is ' + IntToStr(I))); 
    PostMessage(Form1.Handle,WM_UPDATEDATA,Integer(PChar(@Log)),0); 
End; 

procedure TMyThread.Execute; 
var 
    I: Integer; 
begin 
    for I := 0 to 1024 * 65536 do 
    begin 
    if (I mod 65536) == 0 then 
    begin 
     SendLog(I); 
    End; 
    End; 
end; 

nơi WM_UPDATEDATA là một thông điệp tùy chỉnh, định nghĩa dưới đây:

const 
    WM_UPDATEDATA = WM_USER + 100; 

Và trong hình thức chính, nó sẽ làm như sau để cập nhật danh sách:

procedure TForm1.WMUpdateData(var msg : TMessage); 
begin 
    List1.Items.Add(PChar(msg.WParam)); 
end; 

Tuy nhiên, khi Log chuỗi được gửi đến biểu mẫu chính là một biến cục bộ, biến này sẽ bị hủy sau khi gọi SendLog. Trong khi TForm1.WMUpdateData xử lý thông báo một cách không đồng bộ, vì vậy có thể khi nó được gọi, chuỗi Log đã bị hủy. Làm thế nào để giải quyết vấn đề này? Tôi nghĩ rằng có lẽ tôi có thể phân bổ không gian chuỗi trong một không gian hệ thống toàn cầu, và sau đó chuyển nó vào tin nhắn, sau đó sau khi TForm1.WMUpdateData xử lý thông báo, nó có thể phá hủy không gian chuỗi trong không gian toàn cục. Đó có phải là giải pháp khả thi không? Làm thế nào để thực hiện điều này?

Cảm ơn

Answer 1

Sử dụng SendMessage().

PostMessage() sẽ xử lý thư của bạn một cách không đồng bộ, về cơ bản nó đặt vào hàng đợi thư mục tiêu và Trả về ngay lập tức. Vào thời điểm mã trình xử lý truy cập dữ liệu được gửi trong wparam/lparam, người gọi của bạn đã giải phóng chuỗi đó.

Ngược lại, SendMessage() bỏ qua hàng đợi thư và gọi trực tiếp cửa sổ proc (đồng bộ). Vào thời điểm khi SendMessage() trả về, nó an toàn để giải phóng chuỗi.

Answer 2

Ngoài thực tế là bạn đang đăng biến cục bộ, thuộc tính TWinControl.Handle cũng không an toàn. Thay vào đó, bạn nên sử dụng thuộc tính TApplication.Handle hoặc sử dụng AllocateHWnd() để tạo cửa sổ của riêng mình.

Bạn cần phải tự động cấp phát chuỗi trên heap, đăng con trỏ đó lên chuỗi chính và sau đó giải phóng bộ nhớ khi bạn sử dụng xong.

Ví dụ:

procedure TForm1.FormCreate(Sender: TObject); 
begin 
    Application.OnMessage := AppMessage; 
    // or use a TApplicationEvents component... 
end; 

procedure TForm1.FormDestroy(Sender: TObject); 
begin 
    Application.OnMessage := nil; 
end; 

procedure TForm1.AppMessage(var Msg: TMsg; var Handled: Boolean); 
var 
    S: PString; 
begin 
    if Msg.Message = WM_UPDATEDATA then 
    begin 
    S := PString(msg.LParam); 
    try 
     List1.Items.Add(S^); 
    finally 
     Dispose(S); 
    end; 
    Handled := True; 
    end; 
end; 

procedure TMyThread.SendLog(I: Integer); 
var 
    Log: PString; 
begin 
    New(Log); 
    Log^ := 'Log: current stag is ' + IntToStr(I); 
    if not PostMessage(Application.Handle, WM_UPDATEDATA, 0, LPARAM(Log)) then 
    Dispose(Log); 
end; 

Hoặc:

var 
    hLogWnd: HWND = 0; 

procedure TForm1.FormCreate(Sender: TObject); 
begin 
    hLogWnd := AllocateHWnd(LogWndProc); 
end; 

procedure TForm1.FormDestroy(Sender: TObject); 
begin 
    if hLogWnd <> 0 then 
    DeallocateHWnd(hLogWnd); 
end; 

procedure TForm1.LogWndProc(var Message: TMessage); 
var 
    S: PString; 
begin 
    if Message.Msg = WM_UPDATEDATA then 
    begin 
    S := PString(msg.LParam); 
    try 
     List1.Items.Add(S^); 
    finally 
     Dispose(S); 
    end; 
    end else 
    Message.Result := DefWindowProc(hLogWnd, Message.Msg, Message.WParam, Message.LParam); 
end; 

procedure TMyThread.SendLog(I: Integer); 
var 
    Log: PString; 
begin 
    New(Log); 
    Log^ := 'Log: current stag is ' + IntToStr(I); 
    if not PostMessage(hLogWnd, WM_UPDATEDATA, 0, LPARAM(Log)) then 
    Dispose(Log); 
end; 

Answer 3

Nếu bạn có phiên bản D2009 hoặc phiên bản mới hơn, có một cách khác để gửi tin nhắn đến biểu mẫu chính của bạn. TThread.Queue là một cuộc gọi không đồng bộ từ một chuỗi, trong đó một phương thức hoặc thủ tục có thể được thực thi trong chuỗi chính.

Lợi thế ở đây là khung để thiết lập truyền thông điệp ít phức tạp hơn. Chỉ cần vượt qua phương thức gọi lại của bạn khi tạo chuỗi của bạn. Không xử lý và không xử lý rõ ràng việc phân bổ chuỗi/deallocation.

Type 
    TMyCallback = procedure(const s : String) of object; 

    TMyThread = class(TThread) 
    private 
     FCallback : TMyCallback; 
     procedure Execute; override; 
     procedure SendLog(I: Integer); 
    public 
     constructor Create(aCallback : TMyCallback); 
    end; 

constructor TMyThread.Create(aCallback: TMyCallback); 
begin 
    inherited Create(false); 
    FCallback := aCallback; 
end; 

procedure TMyThread.SendLog(I: Integer); 
begin 
    if not Assigned(FCallback) then 
    Exit; 
    Self.Queue( // Executed later in the main thread 
    procedure 
    begin 
     FCallback('Log: current stag is ' + IntToStr(I)); 
    end 
); 
end; 

procedure TMyThread.Execute; 
var 
    I: Integer; 
begin 
    for I := 0 to 1024 * 65536 do 
    begin 
    if ((I mod 65536) = 0) then 
    begin 
     SendLog(I); 
    End; 
    End; 
end; 

---

procedure TMyForm.TheCallback(const msg : String); 
begin 
    // Show msg 
end; 

procedure TMyForm.StartBackgroundTask(Sender : TObject); 
begin 
    ... 
    FMyThread := TMyThread.Create(TheCallback); 
    ... 
end;