nhận được thư mục hiện tại trong VBScript

Question

im cố gắng để có được thư mục hiện hành và sử dụng nó để chạy một ứng dụng không có vấn đề mà tập tin được đặt và không có vấn đề như thế nào con đường được thay đổi

dim fso: set fso = CreateObject("Scripting.FileSystemObject") 
    dim CurrentDirectory 
    CurrentDirectory = fso.GetAbsolutePathName(".") 
    dim Directory 
    Directory = CurrentDirectory\attribute.exe 

    Set WinScriptHost = CreateObject("WScript.Shell") 
    WinScriptHost.Run Chr(34) & "Directory" & Chr(34), 0 
    Set WinScriptHost = Nothing 

làm thế nào để thực sự thiết lập mã này để nó làm những gì tôi muốn nó làm một cách chính xác? Cảm ơn bạn trước!

Answer 1

dòng của bạn

Directory = CurrentDirectory\attribute.exe 

không phù hợp với bất kỳ tính năng tôi đã gặp trong một sách hướng dẫn VBScript. Các công trình sau đây cho tôi, tho không chắc chắn những gì/nơi bạn mong đợi "attribute.exe" để cư trú.

dim fso 
dim curDir 
dim WinScriptHost 
set fso = CreateObject("Scripting.FileSystemObject") 
curDir = fso.GetAbsolutePathName(".") 
set fso = nothing 
Set WinScriptHost = CreateObject("WScript.Shell") 
WinScriptHost.Run curDir & "\testme.bat", 1 
set WinScriptHost = nothing 

Answer 2

Nếu bạn muốn xây dựng một đường đi từ một biến và một tên tập tin, tên tập tin phải được xác định như là một chuỗi (hoặc một biến chứa một chuỗi) và một trong hai nối với biến thư mục biến:

Directory = CurrentDirectory & "\attribute.exe" 

hoặc (tốt hơn) bạn xây dựng con đường bằng cách sử dụng phương pháp BuildPath:

Directory = fso.BuildPath(CurrentDirectory, "attribute.exe") 

Answer 3

bạn có thể sử dụng CurrentDirectory tài sản.

Dim WshShell, strCurDir 
Set WshShell = CreateObject("WScript.Shell") 
strCurDir = WshShell.CurrentDirectory 
WshShell.Run strCurDir & "\attribute.exe", 0 
Set WshShell = Nothing 

Answer 4

Bạn có thể sử dụng WScript.ScriptFullName đó sẽ trở lại đường dẫn đầy đủ của thực hiện kịch bản.

Sau đó bạn có thể sử dụng thao tác chuỗi (JScript dụ):

scriptdir = WScript.ScriptFullName.substring(0,WScript.ScriptFullName.lastIndexOf(WScript.ScriptName)-1) 

Hoặc có được sự giúp đỡ từ FileSystemObject, (VBScript ví dụ):

scriptdir = CreateObject("Scripting.FileSystemObject").GetParentFolderName(WScript.ScriptFullName) 

Answer 5

'-----Implementation of VB6 App object in VBScript----- 
Class clsApplication 
    Property Get Path() 
      Dim sTmp 
      If IsObject(Server) Then 
       'Classic ASP 
       Path = Server.MapPath("../") 
      ElseIf IsObject(WScript) Then 
       'Windows Scripting Host 
       Path = Left(WScript.ScriptFullName, InStr(WScript.ScriptFullName, WScript.ScriptName) - 2) 
      ElseIf IsObject(window) Then 
       'Internet Explorer HTML Application (HTA) 
       sTmp = Replace(Replace(Unescape(window.location), "file:///", "") ,"/", "\") 
       Path = Left(sTmp, InstrRev(sTmp , "\") - 1) 
      End If 
    End Property 
End Class 
Dim App : Set App = New clsApplication 'use as App.Path 

Answer 6

đơn giản :

scriptdir = replace(WScript.ScriptFullName,WScript.ScriptName,"")