Làm thế nào để vẽ sơ đồ trạng thái cổ điển bằng Mathematica?

Question

Có thể và thiết thực cho Mathematica để vẽ một cái gì đó như thế này (được tạo ra bởi Graphviz):

Đây là tốt nhất mà tôi có thể nhận được (nhưng hình dáng và phong cách không thỏa mãn):

Code:

GraphPlot[{{A -> C, "go"}, {C -> B, "gone"}, {C -> D, 
    "went"}, {C -> C, "loop"}}, VertexLabeling -> True, 
DirectedEdges -> True] 

Answer 1

Bạn có thể làm một cái gì đó như thế này bằng cách sử dụng VertexRenderingFunction.

GraphPlot[{{A -> C, "go"}, {C -> B, "gone"}, {C -> D, "went"}, {C -> C, "loop"}}, 
DirectedEdges -> True, 
VertexRenderingFunction -> ({{White, Disk[#, 0.15]}, 
    AbsoluteThickness[2], Circle[#, 0.15], 
    If[MatchQ[#2, A | B], Circle[#, 0.12], {}], Text[#2, #]} &)] 

---

Phương pháp Cập nhật tháng 2 năm 2015

Để duy trì khả năng tương tác sắp xếp lại đồ thị với các công cụ vẽ (double click) người ta phải giữ cho đồ họa đỉnh bên trong GraphicsComplex, với chỉ mục thay vì tọa độ. Tôi tin rằng người ta có thể làm điều này từ VertexRenderingFunction bằng cách sử dụng biến số tăng nhưng có vẻ dễ dàng hơn để thực hiện việc đó với chế độ hậu xử lý. Này hoạt động trong các phiên bản 7 và 10 của Mathematica, có lẽ 8 và 9 cũng như:

GraphPlot[ 
    {{A -> C, "go"}, {C -> B, "gone"}, {C -> D, "went"}, {C -> C, "loop"}}, 
    DirectedEdges -> True 
] /. 
Tooltip[Point[n_Integer], label_] :> 
    {{White, Disk[n, 0.15]}, 
    Black, AbsoluteThickness[2], Circle[n, 0.15], 
    If[MatchQ[label, A | B], Circle[n, 0.12], {}], Text[label, n]} 

Answer 2

Không cần cho vị trí tương tác để có được đỉnh của bạn tại vị trí mong muốn như mr.Wizard gợi ý trong his answer. Bạn có thể sử dụng VertexCoordinateRules cho rằng:

GraphPlot[{{A -> C, "go"}, {C -> B, "gone"}, {C -> D, "went"}, {C -> C, "loop"}}, 
    DirectedEdges -> True, 
    VertexRenderingFunction -> 
      ({{White, Disk[#, 0.15]}, AbsoluteThickness[2], Circle[#, 0.15], 
      If[MatchQ[#2, A | B], Circle[#, 0.12], {}], Text[#2, #]} &), 
    VertexCoordinateRules -> 
      {A -> {0, 0}, C -> {0.75, 0},B -> {1.5, 0.25}, D -> {1.5, -0.25}} 
]