Làm cách nào để chạy thử nghiệm trong bộ thử nghiệm của mô-đun Perl của tôi chỉ khi mô-đun được yêu cầu được cài đặt?

Question

Tôi muốn thêm một bài kiểm tra vào bản phân phối Perl của mình yêu cầu một mô-đun Foo, nhưng bản phân phối của tôi không yêu cầu Foo; chỉ thử nghiệm yêu cầu Foo. Vì vậy, tôi không muốn thêm mô-đun vào các phụ thuộc, nhưng thay vào đó tôi chỉ muốn bỏ qua các bài kiểm tra yêu cầu Foo nếu Foo không có sẵn tại thời gian xây dựng.

Cách thích hợp để thực hiện việc này là gì? Tôi có nên chỉ cần kiểm tra Foo của tôi trong một khối eval cùng với use Foo;, để các thử nghiệm sẽ không chạy nếu tải Foo không thành công? Hoặc là có một cách thanh lịch hơn để làm điều đó?

Answer 1

Test :: More có một tùy chọn để bỏ qua nếu một số điều kiện là không hài lòng, xem dưới đây

SKIP: { 
    eval { require Foo }; 

    skip "Foo not installed", 2 if $@; 

    ## do something if Foo is installed 
}; 

Answer 2

Nếu tất cả các bài kiểm tra đòi hỏi Some::Module đang ở trong một tập tin duy nhất, thật dễ dàng để làm:

use Test::More; 

BEGIN { 
    eval { 
     require Some::Module; 
     1; 
    } or do { 
     plan skip_all => "Some::Module is not available"; 
    }; 
} 

(Nếu bạn đang sử dụng một số thử nghiệm như use Test::More tests => 42; sau đó bạn cũng cần phải sắp xếp để làm plan tests => 42; nếu yêu cầu không thành công.)

Nếu họ là một số nhỏ hơn của các bài kiểm tra trong một file có chứa những thứ khác, sau đó bạn có thể làm một cái gì đó như:

our $HAVE_SOME_MODULE = 0; 

BEGIN { 
    eval { 
     require Some::Module; 
     $HAVE_SOME_MODULE = 1; 
    }; 
} 

# ... some other tests here 

SKIP: { 
    skip "Some::Module is not available", $num_skipped unless $HAVE_SOME_MODULE; 
    # ... tests using Some::Module here 
} 

Answer 3

Từ các tài liệu của Test::More:

SKIP: { 
    eval { require HTML::Lint }; 
    skip "HTML::Lint not installed", 2 if $@; 
    my $lint = new HTML::Lint; 
    isa_ok($lint, "HTML::Lint"); 
    $lint->parse($html); 
    is($lint->errors, 0, "No errors found in HTML"); 
} 

Answer 4

Ngoài ra, declare your test step requirement or recommendation (có sự khác biệt) trong tệp meta distro. Điều này sẽ được chọn bởi một khách hàng thực hiện cài đặt. Tại thời điểm cài đặt, người dùng có thể quyết định có nên cài đặt vĩnh viễn một yêu cầu như vậy hay loại bỏ nó vì nó chỉ được sử dụng để thử nghiệm.