Lệnh batch của Windows để đọc dòng đầu tiên từ tệp văn bản

Question

Làm cách nào để đọc dòng đầu tiên từ tệp văn bản bằng tệp loạt Windows? Vì tệp lớn nên tôi chỉ muốn xử lý dòng đầu tiên.

Answer 1

Đây là tệp lô có mục đích chung để in đầu các dòng n từ một tệp như tiện ích GNU head, thay vì chỉ một dòng.

@echo off 

if [%1] == [] goto usage 
if [%2] == [] goto usage 

call :print_head %1 %2 
goto :eof 

REM 
REM print_head 
REM Prints the first non-blank %1 lines in the file %2. 
REM 
:print_head 
setlocal EnableDelayedExpansion 
set /a counter=0 

for /f ^"usebackq^ eol^=^ 

^ delims^=^" %%a in (%2) do (
     if "!counter!"=="%1" goto :eof 
     echo %%a 
     set /a counter+=1 
) 

goto :eof 

:usage 
echo Usage: head.bat COUNT FILENAME 

Ví dụ:

Z:\>head 1 "test file.c" 
; this is line 1 

Z:\>head 3 "test file.c" 
; this is line 1 
    this is line 2 
line 3 right here 

Nó hiện không đếm dòng trống. Nó cũng phụ thuộc vào giới hạn độ dài dòng hàng loạt là 8 KB.

Answer 2

Bạn có thể cung cấp cho một thử này:

@echo off 

for /f %%a in (sample.txt) do (
    echo %%a 
    exit /b 
) 

chỉnh sửa Hoặc, nói rằng bạn có bốn cột dữ liệu và muốn từ hàng thứ 5 xuống phía dưới, hãy thử này:

@echo off 

for /f "skip=4 tokens=1-4" %%a in (junkl.txt) do (
    echo %%a %%b %%c %%d 
) 

Answer 3

Nhờ thetalkingwalnut với câu trả lời Windows batch command(s) to read first line from text file Tôi đã đưa ra giải pháp sau:

@echo off 
for /f "delims=" %%a in ('type sample.txt') do (
echo %%a 
exit /b 
) 

Answer 4

Hơi xây dựng dựa trên câu trả lời của người khác. Bây giờ cho phép bạn chỉ định các tập tin bạn muốn đọc từ và biến bạn muốn kết quả đưa vào:

@echo off 
for /f "delims=" %%x in (%2) do (
set %1=%%x 
exit /b 
) 

Điều này có nghĩa bạn có thể sử dụng trên như thế này (giả sử bạn gọi nó là getline.bat)

c:\> dir > test-file 
c:\> getline variable test-file 
c:\> set variable 
variable= Volume in drive C has no label. 

Answer 5

Một lót, hữu ích cho stdout redirect với ">":

@for /f %%i in ('type yourfile.txt') do @echo %%i & exit 

Answer 6

Lưu ý, phương pháp tiếp cận tập tin thực thi sẽ được giới hạn ở những giới hạn dòng cho bộ vi xử lý lệnh DOS - xem What is the command line length limit?. Vì vậy, nếu cố gắng xử lý tệp có bất kỳ dòng nào nhiều hơn, thì các ký tự, tập lệnh sẽ chỉ bỏ qua chúng vì không thể giữ giá trị.

Answer 7

Uh bạn guys ...

C:\>findstr /n . c:\boot.ini | findstr ^1: 

1:[boot loader] 

C:\>findstr /n . c:\boot.ini | findstr ^3: 

3:default=multi(0)disk(0)rdisk(0)partition(1)\WINNT 

C:\> 

Answer 8

uh? imo này là đơn giản hơn nhiều

set /p texte=< file.txt 
    echo %texte% 

Answer 9

Vấn đề với giải pháp EXIT/B, khi thực tế nhiều bên trong một tập tin thực thi như chỉ là một phần của nó là như sau. Không có quá trình xử lý tiếp theo trong tập tin batch đã nói sau EXIT/B. Thông thường có nhiều hơn nữa để lô hơn chỉ là một, nhiệm vụ hạn chế.

Để đối phó với vấn đề mà

@echo off & setlocal enableextensions enabledelayedexpansion 
set myfile_=C:\_D\TEST\My test file.txt 
set FirstLine= 
for /f "delims=" %%i in ('type "%myfile_%"') do (
    if not defined FirstLine set FirstLine=%%i) 
echo FirstLine=%FirstLine% 
endlocal & goto :EOF 

(Tuy nhiên, các nhân vật độc cái gọi sẽ vẫn là một vấn đề.)

Thông tin thêm về chủ đề nhận một dòng cụ thể với các lệnh theo lô:
  "23} Làm cách nào để nhận dòng thứ nhất, dòng đầu tiên và dòng cuối cùng của tệp văn bản?"
  http://www.netikka.net/tsneti/info/tscmd023.htm

[Added 28-Aug-2012] Người ta cũng có thể có

@echo off & setlocal enableextensions 
set myfile_=C:\_D\TEST\My test file.txt 
for /f "tokens=* delims=" %%a in (
    'type "%myfile_%"') do (
    set FirstLine=%%a& goto _ExitForLoop) 
:_ExitForLoop 
echo FirstLine=%FirstLine% 
endlocal & goto :EOF 

Answer 10

Hãy thử điều này

@echo off 
setlocal enableextensions enabledelayedexpansion 
set firstLine=1 
for /f "delims=" %%i in (yourfilename.txt) do (
    if !firstLine!==1 echo %%i 
    set firstLine=0 
) 
endlocal 

Answer 11

Một cách khác

setlocal enabledelayedexpansion 
@echo off 
for /f "delims=" %%i in (filename.txt) do (
if 1==1 (
set first_line=%%i 
echo !first_line! 
goto :eof 
))