Làm cách nào để có danh sách thuộc tính trong đối tượng trong Actionscript?

Question

Tôi có một dataprovider và một chức năng lọc cho mảng của tôi được gán cho dataprovider của tôi.

Làm cách nào tôi có thể nhận danh sách các thuộc tính nằm trong mỗi hàng của dataprovider (item.data) khi nó được chuyển đến hàm bộ lọc?

Ví dụ, nếu đối tượng của tôi chứa:

• Object
  • tên
  • email
  • địa chỉ

Sau đó, tôi muốn, trong filterfunction của tôi được có thể xem tên, email và địa chỉ. Thật không may, tôi không biết những gì các tài sản này sẽ được trước khi tay.

Bất kỳ ý tưởng nào?

Answer 1

Nếu đó là một đối tượng năng động, tôi tin rằng bạn chỉ có thể làm một cái gì đó như thế này:

var obj:Object; // I'm assuming this is your object 

for(var id:String in obj) { 
    var value:Object = obj[id]; 

    trace(id + " = " + value); 
} 

Đó là cách nó được thực hiện trong AS2, và tôi tin rằng vẫn hoạt động cho các đối tượng năng động trong AS3. Tôi nghĩ rằng các thuộc tính mà nó sẽ hiển thị bị hạn chế hơn đối với các đối tượng không động.

Answer 2

bạn có thể sử dụng cho .. trong vòng lặp để có được các tên tài sản, hoặc cho mỗi .. trong vòng lặp để có được giá trị tài sản ...

for(var o : * in object){ 
    trace(o + " = " + object[o]); 
} 
/************* OR ******************/ 
for each(var o : * in object){ 
    trace("object has property: " + o); 
} 

Answer 3

cho-in tác phẩm cho các đối tượng năng động chỉ . Đối với các đối tượng đã nhập, bạn cần phải sử dụng một số loại phản ánh để có được tên thuộc tính (ví dụ: http://www.as3commons.org/as3-commons-reflect/index.html)

/Andrei.

Answer 4

Bạn có thể tìm cho

ObjectUtil.getClassInfo(object) 

, xem:

http://livedocs.adobe.com/flex/3/langref/mx/utils/ObjectUtil.html#getClassInfo%28%29

Hãy nhận biết rằng có một lỗi trong nó gây ra nó để điều trị XML như là một kiểu dữ liệu không động . Thông tin thêm về lỗi trong: bugs.adobe.com/jira/browse/SDK-17712

Answer 5

flash.utils.describeType(value:*) cũng sẽ cung cấp cho bạn danh sách thuộc tính trên một đối tượng.

Answer 6

// this method will work for retrieving properties of a *non-dynamic* (typed) object 

// @return - all object properties 
public function getProperties(_obj : *) : Array 
{ 
     var _description : XML = describeType(_obj); 
     var _properties : Array = new Array(); 
     for each (var prop:XML in _description.accessor) 
     { 
       var _property : Object = new Object(); 
       _property.name = String(prop.@name); 
       _property.type = String(simple_type(prop.@type)); 
       _property.access = String(prop.@access); 
       _property.declaredBy = String(prop.@declaredBy); 
       try 
       { 
        _property.value = _obj[_property.name]; 
       } 
       catch (e : Error) 
       { 
        _property.value = ""; 
       } 
       _properties.push(_property) 
     } 
     _properties.sortOn("name"); 
     return _properties; 
} 

// better format for object class information 
private function simple_type(_type : String) : String 
{ 
     var lastIndex : int = _type.lastIndexOf("::"); 
     _type = lastIndex > 0 ? _type.substr(lastIndex + 2) : _type; 
     return _type; 
} 

Answer 7

đối với tôi là chỉ có ích này:

trace('obj = '+getProperties(obj)); 

     public static function getProperties(obj:*):String { 
      var p:*; 
      var res:String = ''; 
      var val:String; 
      var prop:String; 
      for (p in obj) { 
       prop = String(p); 
       if (prop && prop!=='' && prop!==' ') { 
        val = String(obj[p]); 
        if (val.length>10) val = val.substr(0,10)+'...'; 
        res += prop+':'+val+', '; 
       } 
      } 
      res = res.substr(0, res.length-2); 
      return res; 
     } 

và bạn sẽ có được một cái gì đó như thế này:

obj = m:email@ra..., r:true 

Answer 8

Điều này cũng sẽ giúp bạn ..
1.cho Loop - sẽ làm việc dựa trên chỉ số
2. cho mỗi - gọi đệ quy tối đa chiều dài
3. tại - được sử dụng để đọc các tài sản giá trị

 for(var obj : String in objectData) //here objectData is your object 
    { 
     trace("Object Name Is : " + obj); 
     var data : Object = objectData[obj]; //here we get the object value by using the property name 
     trace("Value Is : " + data); //Converts object to string 
    }