Perl readdir theo thứ tự

Question

Có cách nào để đảm bảo đơn đặt hàng từ danh sách được trả về bởi readdir không?

Tôi có đoạn code:

opendir(my $DIR, $src) or die "Error opening $src"; 

# Loop for each file in the directory 
while (my $file = readdir($DIR)) 
{ 
     print "$file\n"; 
} 

Nhưng nó sẽ trả về theo thứ tự ngẫu nhiên. Bây giờ tôi biết có rất nhiều giải pháp thông qua tìm kiếm nhanh trên Google, nhưng tôi không thể tìm thấy thứ tự chính xác tôi cần .. Về cơ bản, tôi muốn các thư mục xuất hiện FIRST hoặc LAST và không nằm giữa các tệp.

Ví dụ, ngay bây giờ nếu tôi có cấu trúc thư mục:

folder 
folder 
file1 
file2 
file3 

tôi nhận được kết quả:

file2 
folder 
folder 
file1 
file3 

Khi thực sự tôi muốn:

folder 
folder 
file1 
file2 
file3 

Hoặc:

file1 
file2 
file3 
folder 
folder 

Bất kỳ cách nào để đạt được điều này?

Cảm ơn.

Answer 1

Bạn có thể sắp xếp bằng cách đặt các thư mục đầu tiên và sau đó sắp xếp theo tập tin/tên dir,

# $src pointing to folder open with opendir 
my @sorted_dir = 
    map $_->[0], 
    sort { 
    $a->[1] <=> $b->[1] 
     || 
    $a->[0] cmp $b->[0] 
    } 
    map [ $_, -f "$src/$_" ], 
    readdir($DIR); 

Trong khi hiệu ứng tương tự có thể đạt được với,

for my $file (sort { -f "$src/$a" <=> -f "$src/$b" } readdir($DIR)) { 
    print "$file\n"; 
} 

nó chậm và không hiệu quả vì nó thường xuyên hơn đi đến kiểm tra hệ thống tập tin nếu mục nhập thư mục là một tập tin đơn giản.

Answer 2

Bạn có thể sử dụng sort để thực hiện việc này, bằng cách xem từng mục nhập của danh sách được trả về readdir.

opendir(my $DIR, '.') or die "Error opening "; 

foreach my $file (sort { -d $a <=> -d $b } readdir($DIR)) { 
    print "$file\n"; 
} 

Điều này sẽ cung cấp cho các thư mục cuối cùng.

Answer 3

Bạn có thể sử dụng part từ List::MoreUtils

#!/usr/bin/env perl 

use strict; 
use warnings; 

use List::MoreUtils 'part'; 

my $dir = shift || '.'; 

opendir my $dh, $dir or die "Cannot open $dir"; 

my ($files, $dirs) = part { -d } sort readdir $dh; 

print "$_\n" for @$files, @$dirs; 

Đối với ý tưởng khác, bạn có thể nhìn vào File::Next.

Answer 4

foreach (sort readdir $dh) {} hoạt động tốt cho tôi.

Ví dụ:

opendir (my $DIR, "$dir") || die "Error while opening $dir: $!\n"; 

foreach my $dirFileName(sort readdir $DIR) 
{ 
     next if $dirFileName eq '.' or $dirFileName eq '..'; 
     print("fileName: $dirFileName ... \n"); 
}